1 files changed, 0 insertions, 75 deletions
diff --git a/app-admin/pass/pass-1.6.2.ebuild b/app-admin/pass/pass-1.6.2.ebuild
deleted file mode 100644
index 10f65b0..0000000
--- a/app-admin/pass/pass-1.6.2.ebuild
+++ /dev/null
@@ -1,75 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/pass/pass-1.6.2.ebuild,v 1.1 2014/05/14 07:49:03 zx2c4 Exp $
-
-EAPI=4
-
-inherit bash-completion-r1 elisp-common
-
-DESCRIPTION="Stores, retrieves, generates, and synchronizes passwords securely using gpg, pwgen, and git"
-HOMEPAGE="http://zx2c4.com/projects/password-store/"
-SRC_URI="http://git.zx2c4.com/password-store/snapshot/password-store-${PV}.tar.xz"
-
-SLOT="0"
-LICENSE="GPL-2"
-KEYWORDS="~amd64 ~x86 ~x86-macos"
-IUSE="+git X zsh-completion fish-completion emacs dmenu importers elibc_Darwin"
-
-RDEPEND="
-	app-crypt/gnupg
-	app-admin/pwgen
-	>=app-text/tree-1.7.0
-	git? ( dev-vcs/git )
-	X? ( x11-misc/xclip )
-	elibc_Darwin? ( app-misc/getopt )
-	zsh-completion? ( app-shells/zsh-completion )
-	fish-completion? ( app-shells/fish )
-	dmenu? ( x11-misc/dmenu )
-	emacs? ( virtual/emacs )
-"
-
-S="${WORKDIR}/password-store-${PV}"
-
-src_prepare() {
-	sed -i -e 's/==/=/g' Makefile || die
-	use elibc_Darwin || return
-	# use coreutils'
-	sed -i -e 's/openssl base64/base64/g' src/platform/darwin.sh || die
-	# host getopt isn't cool, and we aren't brew (rip out brew reference)
-	sed -i -e '/^GETOPT=/s/=.*$/=getopt-long/' src/platform/darwin.sh || die
-	# make sure we can find "mount"
-	sed -i -e 's:mount -t:/sbin/mount -t:' src/platform/darwin.sh || die
-}
-
-src_compile() {
-	:;
-}
-
-src_install() {
-	use zsh-completion && export FORCE_ZSHCOMP=1
-	use fish-completion && export FORCE_FISHCOMP=1
-	default
-	use dmenu && dobin contrib/dmenu/passmenu
-	newbashcomp src/completion/pass.bash-completion pass
-	if use emacs; then
-		elisp-install ${PN} contrib/emacs/*.el
-		elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
-	fi
-	if use importers; then
-		exeinto /usr/share/${PN}/importers
-		doexe contrib/importers/*
-	fi
-}
-
-pkg_postinst() {
-	use emacs && elisp-site-regen
-	if use importers; then
-		einfo "To import passwords from other password managers, you may use the"
-		einfo "various importer scripts found in:"
-		einfo "    ${ROOT}usr/share/${PN}/importers/"
-	fi
-}
-
-pkg_postrm() {
-	use emacs && elisp-site-regen
-}