Subtle live ebuild

2 files changed, 82 insertions, 0 deletions

diff --git a/x11-wm/subtle/Manifest b/x11-wm/subtle/Manifest
new file mode 100644
index 0000000..01e9583
--- /dev/null
+++ b/x11-wm/subtle/Manifest
@@ -0,0 +1 @@
+EBUILD subtle-9999.ebuild 1935 SHA256 1798961c6285f962272f6a472ac83727f6cc2ba4405c059334a216cb4f548331 SHA512 3861c623114a71f3d0e6949240687c76e5e96e88671be4e8a030f507f99c01ebf95530d00203fd6997a88c71c8ff1c0d12b81412f1e503afadd7eb7238435c5e WHIRLPOOL 41ac0360bb9751d1171a5750962bd8d36e76c3ce43566da2bf32feb6b997c91599c5ffd408ef3cdfad89c753c5ff77a2ecfeee1211bbb2acec78dfaf18749332
diff --git a/x11-wm/subtle/subtle-9999.ebuild b/x11-wm/subtle/subtle-9999.ebuild
new file mode 100644
index 0000000..8de1ba5
--- /dev/null
+++ b/x11-wm/subtle/subtle-9999.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/subtle/subtle-9999.ebuild,v 1.5 2012/06/20 19:40:15 radhermit Exp $
+
+EAPI="4"
+USE_RUBY="ruby19"
+
+inherit git-2 ruby-ng toolchain-funcs
+
+EGIT_REPO_URI="git://git.necoro.eu/others/subtle"
+EGIT_PRUNE=1
+
+DESCRIPTION="A manual tiling window manager"
+HOMEPAGE="http://subforge.org/projects/subtle/wiki"
+SRC_URI=""
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug doc +xft xinerama xpm +xrandr +xtest"
+
+RDEPEND="x11-libs/libX11
+	xft? ( x11-libs/libXft )
+	xinerama? ( x11-libs/libXinerama )
+	xpm? ( x11-libs/libXpm )
+	xtest? ( x11-libs/libXtst )
+	xrandr? ( x11-libs/libXrandr )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+ruby_add_rdepend "dev-ruby/archive-tar-minitar"
+ruby_add_bdepend "dev-ruby/rake"
+
+all_ruby_unpack() {
+	git-2_src_unpack
+}
+
+each_ruby_configure() {
+	local myconf
+	use debug && myconf+=" debug=yes" || myconf+=" debug=no"
+	use xft && myconf+=" xft=yes" || myconf+=" xft=no"
+	use xinerama && myconf+=" xinerama=yes" || myconf+=" xinerama=no"
+	use xpm && myconf+=" xpm=yes" || myconf+=" xpm=no"
+	use xtest && myconf+=" xtest=yes" || myconf+=" xtest=no"
+	use xrandr && myconf+=" xrandr=yes" || myconf+=" xrandr=no"
+
+	${RUBY} -S rake -v CC="$(tc-getCC)" destdir="${D}" ${myconf} config || die
+}
+
+each_ruby_compile() {
+	${RUBY} -S rake -v build || die
+}
+
+all_ruby_compile() {
+	use doc && { rake rdoc || die ; }
+}
+
+each_ruby_install() {
+	${RUBY} -S rake -v install || die
+}
+
+all_ruby_install() {
+	dodir /etc/X11/Sessions
+	cat <<-EOF > "${D}/etc/X11/Sessions/${PN}"
+		#!/bin/sh
+		exec /usr/bin/subtle
+	EOF
+	fperms a+x /etc/X11/Sessions/${PN}
+
+	insinto /usr/share/xsessions
+	doins data/${PN}.desktop
+
+	dodoc AUTHORS NEWS
+
+	use doc && dohtml -r html/*
+}
+
+pkg_postinst() {
+	elog "Note that surserver will currently not work since dev-ruby/datamapper"
+	elog "is not in the tree."
+}